processing : tester si un fhichier existe

imdidi · 2017-04-13 18:51:27

Salut a tous
je voudrais sauvegarder des donnés dans un fichier csv sur le site de processing il y a une référence à "Table"
qui a l'air de faire très bien ce que j'ai besoin
la ou j'ai le problème c'est comment tester si la table existe déjà dans un fichier au commencement du programme si elle existe load le fichier sinon fais ce code

Table table;

void setup() {

  table = new Table();
  
  table.addColumn("id");
  table.addColumn("species");
  table.addColumn("name");
  
  TableRow newRow = table.addRow();
  newRow.setInt("id", table.lastRowIndex());
  newRow.setString("species", "Panthera leo");
  newRow.setString("name", "Lion");
  
  saveTable(table, "data/new.csv");
}

// Sketch saves the following to a file called "new.csv":
// id,species,name
// 0,Panthera leo,Lion

Merci
Danny

Mushussu · 2017-04-13 21:04:05

Bonsoir,

Voici de quoi décoincer la situation :

import java.io.*;

FilenameFilter filreCSV = new FilenameFilter() {
  boolean accept(File repertoire, String nom) {
    return nom.toLowerCase().endsWith(".csv");
  }
};

Table table;
File repertoire;
String nomTable, nomRepertoire;

void setup() {
  size(200, 200);
  nomRepertoire = "data";
  repertoire = new File(savePath("") + nomRepertoire);
  nomTable = "maTable.csv";
  File[] fichiers = repertoire.listFiles(filreCSV);
  boolean existe = false;
  if (fichiers != null) {
    for (File f : fichiers) {
      println(f.getName());
      if (f.getName().equals(nomTable)) {
        existe = true;
      }
    }
  }
  if (existe) {
    table = loadTable(nomTable, "header");
  } else {
    table = new Table();

    table.addColumn("id");
    table.addColumn("species");
    table.addColumn("name");

    TableRow newRow = table.addRow();
    newRow.setInt("id", table.lastRowIndex());
    newRow.setString("species", "Panthera leo");
    newRow.setString("name", "Lion");
    saveTable(table, "data/" + nomTable);
  }
}

void draw() {
}

imdidi · 2017-04-14 14:16:40

coul merci
ca ma beaucoup aider

Annonce

#1 2017-04-13 18:51:27 tester si un fhichier existe

tester si un fhichier existe

#2 2017-04-13 21:04:05 Re : tester si un fhichier existe

Re: tester si un fhichier existe

#3 2017-04-14 14:16:40 Re : tester si un fhichier existe

Re: tester si un fhichier existe

Pied de page des forums