Salut Besseo et bienvenue!

Tu peux utiliser un tableau pour stocker les touches qui sont en train d'être appuyées, voila un petit exemple qui fonctionne avec les touches g, h, y, b pour faire se déplacer un cercle. C'est adapté d'une discussion sur l'ancien forum processing! https://processing.org/discourse/beta/n … 08305.html

int nrKeys = 0;
PFont font;
boolean[] downKeys = new boolean[256];
float x = 50;
float y = 50;

void setup() {
size(200,200);
fill(255);
font = createFont("Courier", 20);
textFont(font);
}

void draw() {
background(0);

// afficher l'etat des touches pressees
nrKeys = 0;
for (int i=0; i<downKeys.length; i++) {
   if (downKeys[i]) {
     nrKeys++;
     text((char)i, 10 * nrKeys, height/2);
   }
}
fill(255, 255);
text("Nr. of Keys: " + nrKeys, 20,20);

// modifier les valeurs des variables en fonction des touches appuyees
// g : mouvement vers la gauche en x
// h : mouvement vers la droite en x
// y : mouvement vers le haut en y
// b : mouvement vers le bas en y
if (downKeys['g']) x -= 1;
if (downKeys['h']) x += 1;
if (downKeys['y']) y -= 1;
if (downKeys['b']) y += 1;

// tracer un cercle à la position x, y
fill(255, 0, 0, 127);
ellipse(x, y, 10, 10);

}

void keyPressed() {
println(key);
if (key<256) {
   downKeys[key] = true;
}
}

void keyReleased() {
if (key<256) {
   downKeys[key] = false; 
}
}