bonjour

merci pour tes corrections ,mais il me semble que j’avais testez ce système et la balle apparaît toujours au même endroit donc elle fait toujours la même trajectoire,avec ce générateur de positions aléatoire je voulais faire apparaître la balle sur d'autres endroits dans l’écran ,mais à première vue ça ne fonctionne pas ,et je ne sais pas pourquoi ,pourtant cala parait logique .Par contre si on enlève la trajectoire de la balle le générateur fonctionne on vois bien les balles aparaitres à différentes positions c'est pour ça que je ne comprend pas .enfin si tu as une idée elle serai la bienvenue.

remerciements

fabrice

bonjour

merci pour le programme,je viens de le tester,mais la balle apparaît à différentes positions si tu relance le programme sinon elle reste toujours au même endroit,c'est pour cela que j'avais mis les random dans draw,
j'ai donc changez les fonctions random de ton programme les balles apparaissent bien dans des positions différentes
mais il n'y a plus de rebonds c'est pourquoi je ne comprends pas pourquoi ça fonctionne sans le rebond et pas avec?
Je pense avoir compris en testant un autre programme il faudrait mettre la fonction random dans un sous programme et appeler ce sous programme à la fin du rebond de la balle et ainsi changer sa position,ce qui permettrai au cycle de se finir,enfin ce n'est pas très clair ce que je raconte mais je pense que tu as compris d'ou venais le problème.Je vais essayer de tester ce truc,maintenant i ne me reste plus qu'à regarder comment faire un sous-programme avec processing.

remerciements

fabrice

bonjour

en fin de compte je souhtais faire apparaître des balles qui bougent en même temps,j'ai fait un programme mais une seule balle bouge.
int deplacementX, deplacementY;
float x, y,dx,dy;
int i;

void setup() {

size(800,800);

deplacementX = 5;
deplacementY = -3;

noStroke();
fill(0,0,0,255);
}


void draw() {
dessin_balles();
  bouger();
rebondir();
dessiner();

}

void dessin_balles()
{
if(i<20)
{
     x=random(0,400);
    y=random(0,400);
    i=i+1;

  }
    ellipse(x,y,15,15);
   }





void rebondir() {

if (x > width) {
   deplacementX = -5;
}

if (x < 0) {
   deplacementX = 5;
}

if (y > width) {
   deplacementY = -3;
}

if (y < 0) {
   deplacementY = 3;
}

}


void bouger() {
x = x + deplacementX;
y = y + deplacementY;
}


void dessiner() {
ellipse(x,y,15,15);


}
la les balles apparaissent de façon alleatoire

C'est plus clair.
Pour cela il faut utiliser un tableau "Array" pour pouvoir traiter l'ensemble des balles avec une boucle. Comme une balle a une position et une direction, on peut structurer cela avec une classe "class".

Balle[] balles;

void setup() {
  size(400, 400);
  balles = new Balle[20];
  for (int i = 0; i < balles.length; i++) {
    balles[i] = new Balle(random(0, 400), random(0, 400), 8);
  }
}

void draw() {
  background(255);
  for (int i = 0; i < balles.length; i++) {
    balles[i].mettreAJour();
    balles[i].afficher();
  }
}

class Balle {
  PVector position;
  PVector direction;
  int rayon;

  Balle(float _posX, float _posY, int _rayon) {
    position = new PVector(_posX, _posY);
    rayon = _rayon;
    direction = PVector.random2D();
    direction.mult(2);
  }

  void mettreAJour() {
    position.add(direction);
    if ((position.x < 0) || (position.x > width)) {
      direction.x *= -1;
    }
    if ((position.y < 0) || (position.y > height)) {
      direction.y *= -1;
    }
  }

  void afficher() {
    fill(0);
    ellipse(position.x, position.y, 2 * rayon, 2 * rayon);
  }
}