///////////////////////////////////////////////////
// Bon anniversaire Codelab
//
// Creation : 29 02 2016
// Par : Mushussu
//
// Merci Emoc pour ces partages de connaissances
///////////////////////////////////////////////////

import processing.video.*;

Capture video;

float largeurBandeJaune, largeurBandeNoire, largeurCarre;
int largeur, hauteur;

void setup() {
  size(615, 464);
  video = new Capture(this, 640, 480);
  video.start();
  largeurBandeJaune = 7.5; // Taille originales des bandes du site
  largeurBandeNoire = 6.5;
  largeur = 45;
  hauteur = 34;
  largeurCarre = largeurBandeJaune + largeurBandeNoire;
  noStroke();
  fill(255, 255, 0);
}

void draw() {
  if (video.available()) {
    background(0);
    video.read();
    video.loadPixels();
    for (int j = 0; j < hauteur; j++) {
      for (int i = 0; i < largeur; i++) {
        pushMatrix();
        translate(width - i * largeurCarre, j * largeurCarre);
        rotate(-QUARTER_PI);
        rect(-(largeurCarre + 8) / 2, - largeurCarre / 2, largeurCarre + 8, map(luminositeCarre(video, i, j), 0, 255, 1, 8));
        popMatrix();
      }
    }
  }
}

int luminositeCarre(PImage img, int x, int y) {
  int luminosite = 0;
  x *= largeurCarre;
  y *= largeurCarre;
  luminosite =  (int)brightness(img.pixels[y * img.width + x]);
  return luminosite;
}

void keyPressed() {
  if (key == ' ') {
    saveFrame("sauvegarde.png");
  }
}