bonjour

je voudrais détecter la distance entre plusieurs objets en mouvements pour des collisions, je comprends comment faire avec deux objets mais pas avec 10 ou plus avec les méthodes de classe.Car si je mets dans draw
balle[i].collisions je ne vois pas apres comment je compares les distances des balles à moins de faire des boucles et de tester les balles les unes par rapport aux autres ce qui va faire des milliers de calculs

int nb=100;
Balle[]balle=new Balle[nb];
void setup() {
size(800,700,P3D);
for(int i=0;i<nb;i++)
  {
   balle[i]=new Balle(random(50,500),random(50,500));
}
}
void draw() {
background(255);
for(int i=0;i<nb;i++)
{
balle[i].rebondir();
balle[i].bouger();
balle[i].dessiner();
}
}
class Balle{
  float x;
  float y;
  float deplacementX;
  float deplacementY;
Balle(float dx,float dy)
{
  x=dx;
  y=dy;
   deplacementX= random(-1,1);
  deplacementY= random(-1,1);
  }
void rebondir() {
  if (x > width) {
   deplacementX = -1;
}
  if (x < 0) {
   deplacementX = 1;
}
  if (y >height) {
   deplacementY = -1;
}
  if (y < 0) {
   deplacementY =1;
}

}
void bouger() {
x = x + deplacementX;
y = y + deplacementY;
}
void dessiner() {
  fill(255,0,255);
 
ellipse(x,y,15,15);
}
}
merci

Pour chaque balle tu dois tester les autres balles environnantes. Quand tu as une position avec un x et un y, il est préférable d'utiliser des PVector pour manipuler les distances plus aisément.

int nb=10;

Balle[]balle=new Balle[nb];
void setup() {
  size(800, 700, P3D);
  for (int i=0;i<nb;i++) {
    balle[i]=new Balle(random(50, 500), random(50, 500));
  }
}

void draw() {
  background(255);
  for (int i=0;i<nb;i++) {
    balle[i].rebondir();
    balle[i].bouger();
  }
  for (int i=0;i<nb;i++) {
    for (int j = i + 1 ; j < nb; j++) {
      balle[i].collision(balle[j]);
    }
  }
  for (int i=0;i<nb;i++) {
    balle[i].dessiner();
  }
}

class Balle {
  PVector position;
  float deplacementX;
  float deplacementY;
  int rayon;
  boolean bing;

  Balle(float dx, float dy) {
    position = new PVector(dx, dy);
    deplacementX= random(-1, 1);
    deplacementY= random(-1, 1);
    rayon = 20;
    bing = false;
  }

  void rebondir() {
    if (position.x > width) {
      deplacementX = -1;
    }
    if (position.x < 0) {
      deplacementX = 1;
    }
    if (position.y >height) { 
      deplacementY = -1;
    }
    if (position.y < 0) {
      deplacementY =1;
    }
  }
  void bouger() {
    position.x += deplacementX;
    position.y += deplacementY;
    bing = false;
  }

  void dessiner() {
    if (bing) {
      fill(255, 0, 0);
    } 
    else {
      fill(255, 0, 255);
    }
    ellipse(position.x, position.y, 2 * rayon, 2 * rayon);
  }

  void collision(Balle balleExt) {
    float distance = position.dist(balleExt.position);
    if (distance < 2 * rayon) {
      bing = true;
      balleExt.bing = true;
    }
  }
}

merci pour tes explications et ton programme c'est beaucoup plus clair maintenant ,et pour le programme vecteur,
car je me demandais quel angle il calculait ,je pensait qu'il me renvoyait l'angle de la tangente,c'est pour ça que je trouvais bizarre .

merci encore.

fabrice.

Eviv baledoc